# SPDX-License-Identifier: GPL-3.0-or-later

cmake_minimum_required(VERSION 3.16)

project(libtetra VERSION 0.1.0 LANGUAGES C)

if(CMAKE_CROSSCOMPILING)
    set(TETRA_HOST_DEFAULT OFF)
else()
    set(TETRA_HOST_DEFAULT ON)
endif()

option(TETRA_BUILD_TOOLS "Build host tools" ${TETRA_HOST_DEFAULT})
option(TETRA_BUILD_TESTS "Build unit tests (Catch2)" ${TETRA_HOST_DEFAULT})
option(TETRA_ENABLE_CRYPTO "Build TEA/TB5 and TMO decryption support" OFF)
option(TETRA_UPLINK_DETECT
       "Recognise TMO uplink signals while not synchronised" ON)
option(TETRA_UPLINK_DECODE
       "Decode TMO uplink bursts while not synchronised to a downlink" ON)

# These values affect public receiver-context layouts and must match between
# libtetra and every consumer. Configure them here; the generated public
# header rejects conflicting downstream -D overrides.
set(TETRA_TMO_MAX_SDU_BITS 2632 CACHE STRING
    "Maximum reassembled TMO TM-SDU size in bits")
set(TETRA_DMO_MAX_SDU_BITS 2632 CACHE STRING
    "Maximum reassembled DMO DM-SDU size in bits")
set(TETRA_TMO_MAX_CALLS 8 CACHE STRING
    "Maximum number of simultaneously tracked TMO calls")
set(TETRA_SYNC_MAX_ERRORS 4 CACHE STRING
    "Maximum hard bit errors accepted in a sync sequence (0..38)")

foreach(_value TETRA_TMO_MAX_SDU_BITS TETRA_DMO_MAX_SDU_BITS TETRA_TMO_MAX_CALLS)
    if(NOT "${${_value}}" MATCHES "^[1-9][0-9]*$")
        message(FATAL_ERROR "${_value} must be a positive integer")
    endif()
endforeach()
if(NOT "${TETRA_SYNC_MAX_ERRORS}" MATCHES "^[0-9]+$")
    message(FATAL_ERROR "TETRA_SYNC_MAX_ERRORS must be an integer from 0 to 38")
endif()
if(TETRA_SYNC_MAX_ERRORS GREATER 38)
    message(FATAL_ERROR "TETRA_SYNC_MAX_ERRORS must be an integer from 0 to 38")
endif()

if(TETRA_ENABLE_CRYPTO)
    set(TETRA_ENABLE_CRYPTO_VALUE 1)
else()
    set(TETRA_ENABLE_CRYPTO_VALUE 0)
endif()
if(TETRA_UPLINK_DETECT)
    set(TETRA_UPLINK_DETECT_VALUE 1)
else()
    set(TETRA_UPLINK_DETECT_VALUE 0)
endif()
if(TETRA_UPLINK_DECODE)
    set(TETRA_UPLINK_DECODE_VALUE 1)
else()
    set(TETRA_UPLINK_DECODE_VALUE 0)
endif()
set(TETRA_GENERATED_INCLUDE_DIR "${CMAKE_CURRENT_BINARY_DIR}/generated")
file(MAKE_DIRECTORY "${TETRA_GENERATED_INCLUDE_DIR}/tetra")
configure_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/tetra_config.h.in"
    "${TETRA_GENERATED_INCLUDE_DIR}/tetra/tetra_config.h"
    @ONLY
)

if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
    set(CMAKE_BUILD_TYPE RelWithDebInfo)
endif()

add_library(tetra STATIC
    src/common.c
    src/dmo_rx.c
    src/l1/burst.c
    src/l1/l1.c
    src/l2/coding.c
    src/l2/conv.c
    src/l2/dmo_mac.c
    src/l2/lmac.c
    src/l2/speech.c
    src/l2/tmo_mac.c
    src/l2/tmo_ul_mac.c
    src/l3/dmo_cc.c
    src/l3/lip.c
    src/l3/sds.c
    src/l3/tmo_l3.c
    src/l3/tmo_mle.c
    src/tmo_rx.c
    src/util/bits.c
)

set_target_properties(tetra PROPERTIES
    C_STANDARD 17
    C_EXTENSIONS ON
    OUTPUT_NAME tetra
)

if(TETRA_ENABLE_CRYPTO)
    target_sources(tetra PRIVATE
        src/crypto/tea.c
        src/crypto/tea1.c
        src/crypto/tea2.c
        src/crypto/tea3.c
        src/crypto/tb5.c
        src/crypto/ta61.c
        src/crypto/hurdle.c
        src/crypto/taa1.c
        src/tmo_crypto.c
    )
    # Vendored osmo-tetra cipher (AGPL-3.0+); built without the strict
    # warnings applied to libtetra's own sources. -fno-strict-aliasing is
    # required: these files read and write the same buffers through both
    # uint8_t and uint32_t lvalues, which is undefined under the default
    # type-based aliasing rules and can be miscompiled at -O2.
    set_source_files_properties(
        src/crypto/hurdle.c src/crypto/taa1.c
        PROPERTIES COMPILE_OPTIONS "-w;-fno-strict-aliasing")
endif()

target_include_directories(tetra
    PUBLIC
        $<BUILD_INTERFACE:${TETRA_GENERATED_INCLUDE_DIR}>
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:include>
    PRIVATE
        ${CMAKE_CURRENT_SOURCE_DIR}/src
)

target_compile_options(tetra PRIVATE
    -Wall -Wextra -ffunction-sections -fdata-sections
)

install(TARGETS tetra EXPORT libtetraTargets ARCHIVE DESTINATION lib)
install(DIRECTORY include/tetra DESTINATION include
        PATTERN "tetra_config.h" EXCLUDE)
install(FILES "${TETRA_GENERATED_INCLUDE_DIR}/tetra/tetra_config.h"
        DESTINATION include/tetra)

include(CMakePackageConfigHelpers)
configure_package_config_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/libtetraConfig.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/libtetraConfig.cmake"
    INSTALL_DESTINATION lib/cmake/libtetra
)
write_basic_package_version_file(
    "${CMAKE_CURRENT_BINARY_DIR}/libtetraConfigVersion.cmake"
    VERSION ${PROJECT_VERSION}
    COMPATIBILITY SameMajorVersion
)
install(EXPORT libtetraTargets
        FILE libtetraTargets.cmake
        NAMESPACE tetra::
        DESTINATION lib/cmake/libtetra)
install(FILES
        "${CMAKE_CURRENT_BINARY_DIR}/libtetraConfig.cmake"
        "${CMAKE_CURRENT_BINARY_DIR}/libtetraConfigVersion.cmake"
        DESTINATION lib/cmake/libtetra)

if(TETRA_BUILD_TOOLS OR TETRA_BUILD_TESTS)
    # Synthetic DMO traffic, shared by tetra_gen and the tests.
    add_library(dmo_scenario STATIC tools/dmo_scenario.c)
    set_target_properties(dmo_scenario PROPERTIES C_STANDARD 17
                                                  C_EXTENSIONS ON)
    target_include_directories(dmo_scenario PRIVATE src)
    target_link_libraries(dmo_scenario PUBLIC tetra)
endif()

if(TETRA_BUILD_TOOLS)
    foreach(tool tetra_demod tetra_rx tetra_gen)
        add_executable(${tool} tools/${tool}.c)
        set_target_properties(${tool} PROPERTIES C_STANDARD 17
                                                 C_EXTENSIONS ON)
        target_compile_options(${tool} PRIVATE -Wall -Wextra)
    endforeach()
    target_link_libraries(tetra_demod PRIVATE m)
    target_link_libraries(tetra_rx PRIVATE tetra)
    target_link_libraries(tetra_gen PRIVATE dmo_scenario m)
endif()

if(TETRA_BUILD_TESTS)
    enable_language(CXX)
    enable_testing()
    find_package(Catch2 3 REQUIRED)

    set(TETRA_TESTS coding dmo sds speech tmo tmo_l3 tmo_ul)
    if(TETRA_ENABLE_CRYPTO)
        list(APPEND TETRA_TESTS crypto)
    endif()
    foreach(t ${TETRA_TESTS})
        add_executable(test_${t} tests/unit/test_${t}.cpp)
        set_target_properties(test_${t} PROPERTIES CXX_STANDARD 14
                                                   CXX_EXTENSIONS OFF)
        target_include_directories(test_${t} PRIVATE src)
        target_compile_definitions(test_${t} PRIVATE
            TETRA_TEST_VECTOR_DIR="${CMAKE_CURRENT_SOURCE_DIR}/tests/vectors")
        target_link_libraries(test_${t} PRIVATE
            tetra dmo_scenario Catch2::Catch2WithMain)
        add_test(NAME ${t} COMMAND test_${t})
    endforeach()
endif()
